Source
Ora possiamo leggere il sorgente, ampiamente - spero – commentato…
(Lo potete scaricare da qui, eventualmente aggiornato):
 https://www.dropbox.com/s/0anlqyhygxo8bgi/ardrotor.ino?dl=0 )
// ArdRotor by I2OIM

//    ardrotor is free software: you can redistribute it and/or modify
//    it under the terms of the GNU General Public License as published by
//    the Free Software Foundation, either version 3 of the License, or
//    (at your option) any later version.

include <avr/wdt.h>   //necessario solo per il watchdog

// costanti per calibrazione                             CALIBRAZIONE
const int alzo0 = 8;                 // lettura ad alzo 0
const int alzo90 = 470;           // lettura ad alzo 90
const int azimut0 = 8;             // lettura in direzione nord
const int azimut360 = 693;     // lettura dopo un giro
const bool calibra = false;       // if true va in calibrazione

// pin
const int left = 8;
const int right = 7;
const int down = 5;
const int up = 6;
const int UpDown = 0;
const int EW = 1;
const int extra = 2;        // interruttore extra corsa
const int canrun = 3;     // interruttore stand-by/run
const int LED = 13;
const int RUNLED = 12;

// variabili
bool initial = true; 		// start-up
float kalzo;              	//  quasi costanti calcolate in setup
float kazimut;            	//        ,,
const int anticipoH = 0;  	// anticipo stop se inerzia importante
const int anticipoV = 0;  	//     ----------------------
int isteresiH = 3;
int isteresiV = 2;
int readA = 0;   // azimuth
int readL = 0;   // angolo
char inputString[10];         	// Stringa in ingresso
char alzo[4];                 	// lettura target alzo
int target_alzo = 0;          	// e traduzione in intero
char angolo[4];               	// lettura target angolo
int target_ang = 0;          	// e traduzione in intero
int real_alzo = 0;            	// alzo letto
int real_ang = 0;            	// angolo letto
int j = 0;                     	// puntatore stringa ricezione
char state[2] = "NN";        	// stato dei comandi (nulla, up, down)
				// state[0] -> alzo, state[1] -> angolo
bool e = false;                	// zona extra corsa

void setup() {
  pinMode(left, OUTPUT);	//preset pins
  digitalWrite(left, LOW);
  pinMode(right, OUTPUT);
  digitalWrite(right, LOW);
  pinMode(down, OUTPUT);
  digitalWrite(down, LOW);
  pinMode(up, OUTPUT);
  digitalWrite(up, LOW);
  pinMode(extra, INPUT_PULLUP);
  pinMode(canrun, INPUT_PULLUP);
  pinMode(LED, OUTPUT);
  pinMode(RUNLED, OUTPUT);
  kalzo = float(alzo90 – alzo0)/90;		// calcolo costante alzo
  kazimut = float(azimut360 – azimut0)/360;	// calcolo costante angolo
  // initialize serial:
  Serial.begin(9600);
  // avvia watchdog
  delay(1000);
  wdt_enable(WDTO_8S);
}

void loop() {
  if (calibra) setting();   		// va al loop di setting.
  
// blocca se interruttore RUN inattivo e libera i comandi manuali del rotore
//       loop in questa routine fino a quando l’interruttore non viene azionato
  while (digitalRead(canrun) == HIGH) {
    digitalWrite(right, LOW);
    digitalWrite(left, LOW);
    digitalWrite(up, LOW);
    digitalWrite(down, LOW);
    digitalWrite(LED, LOW);
    digitalWrite(RUNLED, LOW);
    delay(250);
  }

  digitalWrite(RUNLED, HIGH);	// segnalazione run
 
  if (digitalRead(extra) == LOW) {	// eventuale segnalazione EXTRA rotazione
    e = true;
    digitalWrite(LED, HIGH);
  } else {
    e= false;
    digitalWrite(LED, LOW);
  }

  readIn();		// chiamata della routine di lettura input analogici

  if (initial) {     	// deve star fermo alla accensione: il target viene fissato alla posizione attuale
    target_ang = real_ang;
    target_alzo = real_alzo;
    initial = false;	// non eseguirà più questa sezione della routine
  } else {
    switch (state[0]) {		// aziona output a seconda dello stato
      case 78:  // "N"
        digitalWrite(right, LOW);
        digitalWrite(left, LOW);
        break;
      case 82:  // "R"
        digitalWrite(left, LOW);
        digitalWrite(right, HIGH);
        break;
      case 76:  // "L"
        digitalWrite(right, LOW);
        digitalWrite(left, HIGH);
        break;
      default:
        break;
    }

    switch (state[1]) {		// idem per alzo
      case 78:  // "N"
        digitalWrite(up, LOW);
        digitalWrite(down, LOW);
        break;
      case 85:  // "U"
        digitalWrite(down, LOW);
        digitalWrite(up, HIGH);
        break;
      case 68:  // "D"
        digitalWrite(up, LOW);
        digitalWrite(down, HIGH);
        break;
      default:
        break;
    }
  }
  delay(300);			// evita impulsi troppo brevi ed instabilità
}					// l'impulso minimo sarà di questa durata (mS)

void changeState() {		// routine che definisce lo stato futuro dopo la 
//   reset watchdog!			   la ricezione di una stringa valida.	
  wdt_reset();
  for (int i = 1; i < 4; i++) {               // estrae azimuth e elevazione
    angolo[i - 1] = inputString[i];
  }
  angolo[3] = 0;
  for (int i = 5; i < 8; i++) {
    alzo[i - 5] = inputString[i];
  }
  alzo[3] = 0;
  target_ang = atoi(angolo);
  if (target_ang  < 0) target_ang = 0;
  if (target_ang  >= 360) target_ang = 360;
  target_alzo = atoi(alzo);
  if (target_alzo < 0) target_alzo = 0;
  if (target_alzo > 180) target_alzo = 180;
}

void serialEvent() {		// routine chiamata dalla ricezione di un carattere sulla seriale
  while (Serial.available()) {		// legge tutti i caratteri in coda ricezione, potrebbero essere più di uno
    // get the new byte:
    char inChar = (char)Serial.read();
    inputString[j] = inChar;
    j = j + 1;
    if (j >= 10) j = 0;			// la stringa valida è 10 caratteri
    // if the incoming character is a newline set the flag
    if (inChar == '\r') {
      if (j == 9 && inputString[0] == 87) { 	// scarta stringhe con false chiusure e, se
        changeState();				// valida, chiama la valutazione stato futuro
      }
      j = 0;
    }
  }
}

void readIn() {				// legge input analogici e calibra in gradi
  real_ang = readAnalog(450, EW);		// chiama la routine che legge un pin A/D
  state[0] = 78; // "N";
  if (e) {   // gestione rotazione in extra anglo (>360)
    					// se target < 180, real -= 360 (quadrante 5,6 -> quadrante 1e
    if (target_ang < 180) {
      real_ang = real_ang - 360;              	// quadrante 5 -> 1
      if (target_ang > 90) target_ang = 90;   	// quadrante 6 -> 1 con limite
    } 
//    else {
//      e = false;                              		// reset quadranti extra
//      digitalWrite(LED, LOW);
//    }
  }
  if (target_ang - anticipoH - real_ang <= - isteresiH ) {
    state[0] = 76; // "L";
  }
  if (target_ang  - anticipoH - real_ang >= isteresiH) {
    state[0] = 82; // "R";
  }

  Serial.print("t_ang: ");   			//  serial output x calibrazione
  Serial.print(target_ang);
  Serial.print("; real: ");
  Serial.print(real_ang);
//  Serial.print(" differenza: ");                   //  DEBUG per definizione Isteresi
//  Serial.println(target_ang – real_ang);    //                invia alla seriale l’errore posizione

  
  real_alzo = readAnalog(180, UpDown);
  state[1] = 78; // "N";
  if (target_alzo - anticipoV  - real_alzo >= isteresiV ) {
    state[1] = 68; // "D";
  }
  if (target_alzo - anticipoV - real_alzo <= - isteresiV) {
    state[1] = 85; // "U";
  }
  
  Serial.print(" t_alzo: ");  			// serial output x calibrazione
  Serial.print(target_alzo);
  Serial.print(" r_alzo: ");
  Serial.println(real_alzo);

  return;
}

int readAnalog(int k, int num_input) {  	// lettura input analogico, num_input pin dove leggere	
  						// k parametro angolo (450: azimut, 180 : alzo).
  float x = 0; 				// filtro antidisturbo: media su 5 letture consecutive
  for (int i = 0; i < 5; i++) {
    x = x + analogRead(num_input);
  }
  x = x/5;

  if (k == 450){
    x = x - azimut0;
    x = x/kazimut;
  }
  if (k == 180) {
    x = x - alzo0;
    x = x/kalzo;
  }

  x = int(10*x+5);				// arrotondo all’intero
  x = int(x/10);
  if (x < 0) x = 0;
  if (x > k) x = k;
  return(x);
}

void setting() {				// per setup: legge i valori e li tarsmette
  int angolo;				// sulla seriale – for ever!
  int vangolo;
  while(true) {
    angolo = analogRead(EW);
    vangolo = analogRead(UpDown);
    Serial.print("direzione: ");
    Serial.print(angolo);
    Serial.print("; alzo: ");
    Serial.println(vangolo);
    delay(500);
//    reset watchdog!
    wdt_reset();
  }
}

Nota: questo codice è open source con licenza Creative Common, quindi potete farci quello che volete (anche farlo pagare) ma le modifiche devono essere pubblicate ovviamente in open source anch’esse, e va citato l’autore originale (I2OIM).
Per prima cosa, caricando lo script in Arduino, ponete la riga 15 a 
		const bool calibra = true
così facendo il programma partirà in calibrazione, trasmettendo, sulla seriale, i valori letti sui canali analogici anziché pilotare il rotore; portate quindi il rotore sia a zero gradi di alzo e azimut, sia a 360° in azimut e 90° di alzo ed annotate i valori trasmessi (*). Questi vanno inseriti nelle righe da 11 a 14; quindi nella riga 15 inserite “false“. Finito.
Ok, connettete rotore e PC e buon SAT_QSO.

Tutto ben confuso? È solo da studiare. Vi consiglio anche di simulare con “Simulator for Arduino” se volete fare miglioramenti e/o adattarlo ad altri rotori, magari solo azimutali. Commentate il watchdog ed inserite in input seriale  W180 090\r o un valore a vostro piacimento; coi cursori potete simulate l’ingresso analogico (e i comandi RUN ed EXTRA)

Nota
* per leggere i dati dovete leggere l’output del canale che viene usato tra PC e ArdRotor. Supponendo sia ad esempio com3, basta aprire un prompt comandi (tasto windows + cmd) e scrivere “copy com3: con:” oppure usare putty o analoghi emulatori di terminale. 

